Objective Labs - Mac OS scripting Solutions by Tim Conner

Sort Clipboard Contents Applescript

(* This script will convert anything in the finder to text, and then sort that text. Procedure is to copy an item. Run this script from the script menu, then paste.
*)
set the clipboard to list_to_string(ASCII_Sort(string_to_list(«class ktxt» of ((the clipboard as text) as record), return)), return)

on ASCII_Sort(my_list)
	--from apple
	set the index_list to {}
	set the sorted_list to {}
	repeat (the number of items in my_list) times
		set the low_item to ""
		repeat with i from 1 to (number of items in my_list)
			if i is not in the index_list then
				set this_item to item i of my_list as text
				if the low_item is "" then
					set the low_item to this_item
					set the low_item_index to i
				else if this_item comes before the low_item then
					set the low_item to this_item
					set the low_item_index to i
				end if
			end if
		end repeat
		set the end of sorted_list to the low_item
		set the end of the index_list to the low_item_index
	end repeat
	return the sorted_list
end ASCII_Sort

on snr(the_string, search_string, replace_string)
	return my list_to_string((my list_to_string(the_string, search_string)), replace_string)
end snr

on list_to_string(the_list, the_delim)
	my atid(the_delim)
	set the_string to (every text item of the_list) as string
	my atid("")
	return the_string
end list_to_string

on string_to_list(the_string, the_delim)
	my atid(the_delim)
	set the_list to (every text item of the_string) as list
	my atid("")
	return the_list
end string_to_list

on atid(the_delim)
	set Applescript's text item delimiters to the_delim
end atid

Panther users click here to open in Apple's script Editor.

Export Apple Mail to Gmail Applescript

This script will automate the forwarding of your Mail.app email messages to your
gmail account. Keep in mind that it will take 2 seconds per email so make sure you 
allow yourself enough time. For more information on the gml.py necessary for this 
script, go to http://www.marklyon.org/gmail/.

Make sure you've downloaded the python source code from
http://www.marklyon.org/gmail/gml.tar and placed it on your desktop. chmod the
file to 755 if you have permission problems.

Disclaimer: This script was written in a few minutes so there could
be some problems with it, and it could use a bit of error trapping.
Here it is with no guarantee it wont burn your house down and destroy
all your email messages, but I'd be very surprised if it did.

-- Your Gmail email address
property myGMailAddress : "youremail@gmail.com"

-- Path to your Mailboxes
property mymailboxpath : "/Users/yourusername/Library/Mail/Mailboxes/"

--Path to the downloaded gml.py file
property gmlFilePath : "/Users/yourusername/Desktop/gml.py"

--Exclude mailboxes that contain any of these words add any words you like
property myExcludedMailboxesList : {"cache", "junk", "deleted", "drafts", "sent", "outbox", "info.plist", ".DS_Store"}

-- Don't change this unless you know what you're doing
property alternateSMTPServer : "gsmtp171.google.com"

try
	set myMailBoxes to (list folder (mymailboxpath as POSIX file))
	set finalMBoxList to {}
	repeat with eachMbox in myMailBoxes
		set exclude to false
		repeat with eachExclusion in myExcludedMailboxesList
			if eachMbox contains eachExclusion then
				set exclude to true
			else if eachMbox does not contain ".mbox" then
				set exclude to true
			end if
		end repeat
		if exclude is false then set finalMBoxList to finalMBoxList & eachMbox
	end repeat
	
	repeat with eachMbox in finalMBoxList
		set gmlCommand to "/usr/bin/env python '" & gmlFilePath & "' mbox '" & mymailboxpath & eachMbox & "/mbox' " & myGMailAddress & " " & alternateSMTPServer
		tell application "Terminal"
			do script gmlCommand
		end tell
	end repeat
on error err
	display dialog err giving up after 20
end try

Panther users click here to open in Apple's script Editor.

Applescript String Parsing

Panther users click here to open in Apple's script Editor.

Better Mount Volumes script

Panther users click here to open in Apple's script Editor.

Fast Is File Busy Check (Mac OS X)

Panther users click here to open in Apple's script Editor.

Load Text File to String

Panther users click here to open in Apple's script Editor.

Remove dot-3 Extension from File Name

Panther users click here to open in Apple's script Editor.

Blogger API testing script

(* ==== Blogger API Tester script ==== *)
-- Created By: Tim Conner
-- http://www.objectivelabs.com/
-- Version -.2
-- July 19, 2002

(* ==== About this script ====
This script was written for builders of Blogger api's to test how applescript and more
importantly the OS X xmlrpc library will interpret the results they are returning.
A great debugging tool.
 *)

(* ==== How to use this script ====
 Uncomment the lines in the "on run" portion of the script individually to test each function.
Be sure to specify your properties accurately below. To view the results select "Show Result:" 
form the controls menu of script Editor. To view it step by step choose "open event log" from
the controls menu in script editor. The relult will show as a list of items as the Mac OS X
implimentation of XML-RPC interprets them.
 *)

(* ==== Properties ==== *)
property appkey : "4FCE1E1F9E2DC89044F09D583390AB8A36F4903E" -- my appkey code to blogger backend
property username : "username" -- your username
property myPassword : "password" -- your password
property apiurl : "http://plant.blogger.com/api/RPC2" -- the complete api url
property blogid : "1" -- Id of the weblog you'd like to post to
property content : "This is a test post" -- content of the post
property noOfPosts : 1 -- the number of posts to return for get recent posts. must be integer
property templateType : "main" -- main or archive
property template : "This is my new blogger template" --the template you want to send to your server 
property postid : "246" --id of post to edit. Must be in quotes
property publish : true -- set default publish property (it may be overridden by the function [see delete post])

on run
	(* un comment each line individually to test each functions results *)
	set theResult to getUsersBlogs(username, myPassword)
	--getUserInfo(username, myPassword)
	--newPost(blogid, content, publish)
	--editPost(postid, content, publish)
	--deletePost(postid)
	display dialog blogname of theResult
	
	--getRecentPosts(blogid, username, myPassword, noOfPosts)
	--getTemplate(blogid, templateType)
	--setTemplate(blogid, template, templateType)	
end run

(* ==== You shouldn't have to edit below this line ====*)

-- Sends the XML-RPC code to the remote server
on tellBloggerAPI(methodName, params)
	using terms from application "http://www.apple.com"
		-- any url works here. Fools applescript into using xml-rpc terms
		tell application (apiurl as text)
			set myResult to call xmlrpc {method name:methodName, parameters:{appkey} & params}
			return myResult
		end tell
	end using terms from
end tellBloggerAPI

-- Returns a list of blogs owned by a given user.
on getUsersBlogs(username, thePassword)
	set params to {username, thePassword}
	return tellBloggerAPI("blogger.getUsersBlogs", params)
end getUsersBlogs

-- Creates a new post, and possibly it is published
on newPost(blogid, content, publish)
	set params to {blogid, username, myPassword, content, publish}
	return tellBloggerAPI("blogger.newPost", params)
end newPost

-- replaces the contents of the specified post with the content variable
on editPost(postid, content, publish)
	set params to {postid, username, myPassword, content, publish}
	return tellBloggerAPI("blogger.editPost", params)
end editPost

-- deletes the post of the specified post id
on deletePost(postid)
	set publish to true -- so it automatically publishes your delete
	set params to {postid, username, myPassword, publish}
	return tellBloggerAPI("blogger.deletePost", params)
end deletePost

-- returns the contents of the template of the type specified
on getTemplate(blogid, templateType)
	set params to {blogid, username, myPassword, templateType}
	return tellBloggerAPI("blogger.getTemplate", params)
end getTemplate

-- saves the specified template with the contents of the template variable
on setTemplate(blogid, template, templateType)
	set params to {blogid, username, myPassword, template, templateType}
	return tellBloggerAPI("blogger.setTemplate", params)
end setTemplate

-- returns the contents of the number of posts specified. Many api's return all of the posts if a number is not specified
on getRecentPosts(blogid, username, myPassword, noOfPosts)
	set params to {blogid, username, myPassword, noOfPosts}
	return tellBloggerAPI("blogger.getRecentPosts", params)
end getRecentPosts

on getUserInfo(username, myPassword)
	set params to {username, myPassword}
	return tellBloggerAPI("blogger.getUserInfo", params)
end getUserInfo

Panther users click here to open in Apple's script Editor.

XML or HTML tag parser handler

(*
This handler is intended to accept a string input, and remove the contents of a specific tag within that sting input. This is great for getting string contents out of xml or html files. For example, if you want to get the title of an html document you call
tagParse(yourFileContents, "")

it would return the text between the two title tags. 
*)
on tagParse(thisText, openTag, closeTag)
	set new_text to ""
	set strlen to the length of thisText
	set taglen to (the length of openTag) - 1
	set closeTagLen to (the length of closeTag) - 1
	set stridx to 1
	repeat until (stridx + taglen) is greater than strlen
		set thisString to the contents of characters stridx through (stridx + taglen) of thisText as text
		log thisString
		if thisString is openTag then
			set firstChar to stridx + taglen + 1
			--display dialog "the title text starts at character " & firstChar
			repeat until (stridx + closeTagLen) is greater than strlen
				set thisString to the contents of characters stridx through (stridx + closeTagLen) of thisText as text
				log thisString
				if thisString is closeTag then
					return the contents of characters firstChar through (stridx - 1) of thisText as text
				end if
				set stridx to stridx + 1
			end repeat
		end if
		set stridx to stridx + 1
	end repeat
	return "Error:: tag " & openTag & " not found."
end tagParse

Panther users click here to open in Apple's script Editor.

Delete files older than X days with wildcard option

Panther users click here to open in Apple's script Editor.

Folder Maker

Panther users click here to open in Apple's script Editor.

Log Text to Tab Delimited Files

on logFile(theFields, logFileName)
	(* 
	this script is intended to be used to write logs to a tab delimited text file
	
	logfilename is a string
	theFields must be a  list
	logfilename is just the name of your log file
	*)
	try
		tell application "Finder"
			if not (file ((path to desktop folder as text) & logFileName) exists) then
				set theLogFile to make file at folder (path to desktop folder as text)
				set the name of theLogFile to logFileName
				set myFile to open for access file ((path to desktop folder as text) & logFileName) with write permission
			else
				set myFile to open for access file ((path to desktop folder as text) & logFileName) with write permission
			end if
			set endOfFile to get eof myFile
			repeat with eachField in theFields
				set theFieldString to theFieldString & item eachField of theFields & tab
			end repeat
			write (theFieldString & return) to myFile starting at (endOfFile + 1)
			close access myFile
		end tell
	on error err
		display dialog "log file error" & err giving up after 5
		try
			close access ((path to desktop folder as text) & logFileName)
		end try
	end try
end logFile

Panther users click here to open in Apple's script Editor.